**Mostrando anos bissextos**

**Mário Leite**

...

A cada quatro anos o mês de Fevereiro tem 29 dias; e o ano em que isto acontece é denominado “ano bissexto”, com 366 dias (bi 6 = 66), em vez dos 365 dias habituais. O ano bissexto, tal com o o conhecemos, foi introduzido no Calendário Gregoriano pelo [Papa Gregório XIII](https://pt.wikipedia.org/wiki/Papa_Greg%C3%B3rio_XIII) em 1582  para corrigir 5 horas, 48 minutos e 46 segundos que faltam, quando se compara este calendário com o tempo real que o planeta Terra leva para dar uma volta compleda em torno do Sol. Assim, foi resolvido fazer essa correção, acrescentando um dia ao ano, a cada quatro anos, feita no mês de Fevereiro. Mas, embora tivesse sido criado oficialmente 1582, foi implementado a partir de 1583.

Para descobir se um determinado ano é bissexto basta verificar a seguinte condição:

“tem que ser divisível por 4 **E** não pode ser divisível por 100, **OU** ser divisível por 400”.

O programa **“AnosBissextos”** (codificado em Visualg) é uma solução simples para mostrar os anos bissextos, desde 1583 até 2999; e a **figura 1** todos os anos bisssextos desde 1583 até 2400.

-----------------------------------------------------------------------------------------------------------------------------------

Para adquirir o *pdf/e-book* dos meus livros sobre programação, entre em contado pelo *e-mail*: **marleite@gmail com**

-----------------------------------------------------------------------------------------------------------------------------------

**Algoritmo** **"MostraAnosBissextos"**

//Mostra os anos bissexos em um determinado período.

//Em Visualg

//Autor: Mário Leite

//------------------------------------------------------------------------

**Const** ANO1MIN=1583 //define limite inferior [1583: Calendário Gregoriano]

ANO1MAX=2999 //define limite superior

ANO2MIN=1583

ANO2MAX=2999

**Var** j, col, cont, Ano, AnoIni, AnoFim: **inteiro**

Cond, Cond1, Cond2, Cond3, Cond4: **logico**

VetBissex: **vetor**[1..500] **de** **inteiro**

**Inicio**

**Repita** //valida o período

**Escreva**("Digite o ano inicial [min",ANO1MIN,"-max",ANO1MAX,"]: ")

**Leia**(AnoIni)

Cond1 <- ((AnoIni>=ANO1MIN) **E** (AnoIni<=ANO1MAX))

**Escreva**("Digite o ano final [min",ANO2MIN," -max",ANO2MAX,"]: ")

**Leia**(AnoFim)

Cond2 <- ((AnoFim>=ANO2MIN) **E** (AnoFim<=ANO2MAX))

Cond3 <- (AnoIni<=AnoFim) //AnoIni pode ser igual a AnoFim

Cond4 <- (Cond1 **E** Cond2 **E** Cond3)

**Escreval**("")

**Ate**(Cond4) //fim da validação do período

**Escreval**("")

**Escreval**(" Anos bissextos de", AnoIni, " até", AnoFim,":")

**Escreval**(" ----------------------------------------------------------")

{Cria o vetor de anos bissextos}

Cont <- 0

**Para** Ano **De** AnoIni **Ate** AnoFim **Faca**

Cond1 <- ((Ano **Mod** 4 = 0) **E** (Ano **Mod** 100<>0)) **OU** (Ano **Mod** 400=0))

**Se**(Cond1) **Entao** //verifica se Ano é bissexto

cont <- cont + 1

VetBissex[cont] <- Ano

**FimSe**

**FimPara**

{Imprime os anos bissextos em blocos de até dez unidades}

col <- 0

**Para** j **De** 1 **Ate** cont **Faca**

col <- col + 1

**Se**(col<=10) **Entao**

**Escreva**(" ", VetBissex[j])

**Senao**

**Escreval**("")

col <- 1

**Escreva**(" ", VetBissex[j])

**FimSe**

**FimPara**

**Escreval**("")

**Escreval**("")

**Se**(cont=0) **Entao**

**Escreval**(" Não existe nenhum ano bissexto nesse período.")

**FimSe**

**Se**(Cont=1) **Entao**

**Escreval**(" Existe apenas 1 ano bissexto nesse período.")

**FimSe**

**Se**(Cont>1) **Entao**

**Escreval**("Existem",Cont," anosbissextosde",AnoIni,"até", AnoFim,".")

**FimSe**

**Escreval**("")

**FimAlgoritmo**

